Domaci automatizace

[MK]

> Galvanicke propojeni tam bude i s dodatecnou logikou.
> Mohl bych tech 10 instrukci videt? Ja to resivam tak, ze v intervalu
> treba 10 ms testuju vstup, pokud se zmeni, nastavim citac, a kdyz zmeneny
> stav vstupu vydrzi rekneme deset cyklu, prohlasim ho za platny.
> Muj nazor je, ze pokud se da neco osetrit softwarove, je zbytecne
> pridavat dalsi soucastky.


No treba pro x51 to muze byt takhle:
;=============================================================================
;
;                   RUTINA OBSLUHY PRERUSENI OD CASOVACE TH0
;
;=============================================================================
INT_T0: push PSW                ;
        setb RS0                ; Banka '1'
                                ;
        mov  TH0 ,#0FDH         ; Intr <- 1600 Hz pri Q=11.0592 MHz
        mov  TL0 ,#0D0H         ;
                                ;---------------------------------------------
        inc  R0                 ; dalsi zobrazovana pozice
        cjne R0,#38H,Show       ; 0 --> 15
        mov  R0,#28H            ;
        setb P3.4               ; Data '1'
                                ;
        djnz R4,Show            ; citac 100 Hz
        mov  R4,#10             ;
        setb 10H                ; uplynula 0.1s
                                ;---------------------------------------------
Show:   mov  P1,#0FFH           ; nic nezobrazujeme
        clr  P3.5               ; Clk  '0'
        setb P3.5               ; Clk  '1'
        clr  P3.4               ; Data '0'
        mov  P1,@R0             ; zobrazovana hodnota
                                ;---------------------------------------------
        jnb  09H,NoBeep         ; ??? pipat
        cpl  P3.3               ; no jo
        djnz R5,NoBeep          ;
        clr  09H                ; zakaz pipani
        setb P3.3               ;
                                ;---------------------------------------------
NoBeep: djnz R7,NoKey           ; casovani mezery mezi stisky KEY
        inc  R7                 ;
        djnz R6,NoKey           ; casovani mezery mezi stisky KEY
        inc  R6
        jnb  P3.7,NoKey         ;
        mov  R7,#0              ; konstanta casovani KEY
        mov  R6,#7FH            ; konstanta casovani KEY
        setb 08H                ; priznak stlaceni tlacitka
        mov  27H,R0             ; na adrese 27H -> je hodnota tlacitka + 28H
                                ;---------------------------------------------
NoKey:  pop  PSW                ; Banka '0'
 reti                    ;

V ramci preruseni od casovace je obsluhovan 16x7seg displej,
16 tlacitek pripojenych na vystupy 2x74164, ktere zaroven ovladaji
spinace anod pro multiplex a cvici se s buzerem

Jedna se o fragment ze souboru, ktery ma datum posledni aktualizace 
29.3.1989
Je to tedy vlastne jeste takovy pionyr :-)))))))
A ono je to videt i na zapisu :-)))))))))

S pozdravem
MK